Evo. G Tech Team Forum
Welcome to Evo. G Tech Team Forum. We have moved to a new website : www.evogtechteam.com

Thanks you.

by Evo. G Tech Team Management.

【转】批处理(甲兵时代移动盘同名文件夹病毒专杀工具)

View previous topic View next topic Go down

【转】批处理(甲兵时代移动盘同名文件夹病毒专杀工具)

Post by cyjian on December 12th 2014, 10:06

伟大不哭友情提醒:1很想一次性发完,但是无奈于字数限制,唉,发三次,记得要全部复制!
2复制到文本文档中,然后把TXT文档改为bat后缀保存。
3以下为复制代码:

@echo off
::by cjiabing 2010-01-05 CMD@XP
::from 甲兵时代:  
title 甲兵时代移动盘同名文件夹病毒专杀工具(升级改进版2010.1.8)
copy %0 %SYSTEMDRIVE%>nul
COLOR 3C
echo.
echo.
echo                           ★★★ 同名文件夹专杀 ★★★
echo.
echo *******************************************************************************
echo     ★使用说明:
echo     ◇中毒特征:移动盘中的文件夹被隐藏,取而代之的是带有EXE结尾的“文件夹”。其实它并非文件夹,而是病毒程序,它的图标是文件夹,扩展名 为.EXE,大小约为1.20M-1.44M。它阻止显示隐藏文件,通过潜伏在电脑和移动盘上达到自动传播。新闻报道80%的办公电脑和移动盘中过该毒。
echo     ◇本工具几经升级,能有效发现和清除病毒,修复移动盘中的文件夹。
echo     ◇本工具功能有限,使用需自担风险。
echo     ◇本工具免费共享,敬请关注更新(甲兵时代:  )。
echo *******************************************************************************
:start
echo.
echo     ★功能选项:
echo.
echo        【1】一键杀毒:一键同时清除系统和优盘中的病毒。
echo        【2】免疫修复:显示和隐藏文件,清除autoruns和desktop,禁用自动播放。
echo        【3】清理垃圾:清理系统临时文件。
echo        【4】退出。
echo.
set /p inf=    ◇请根据需要输入序号,并按回车:
if "%inf%" == "1" goto kill
if "%inf%" == "2" goto auto
if "%inf%" == "3" goto clean
if "%inf%" == "4" goto exit
:kill
cls
echo.
echo     开始杀毒,正在检查进程……
echo.
echo.
::注意:本程序检查进程名称中是否含有数字来判断是否病毒,除了360tray.exe其它含有数字的进程名称可能被当做病毒处理,为防止可能的误判,请关闭其它进程后再杀毒。
for /f %%a in ('tasklist') do echo %%a |findstr "[0-9]" |findstr /i /v "360tray.exe" >>psyf.txt
for /f %%a in (psyf.txt) do cls &echo 发现可疑进程:%%a   &taskkill /f /im %%a
taskkill /f /im XP*
tskill explorer
taskkill /f /im explorer.exe
echo   清除病毒……
for /f %%a in (psyf.txt) do (wmic process where name="%%a" get ExecutablePath |find /i ".exe")>>fpath.txt
for /f %%a in (fpath.txt) do if exist %%a (attrib -h -r -s -a %%)&(DEL /F /Q %%a)
for /f "delims=" %%a in (psyf.txt) do (
for /r %SYSTEMROOT%\system32   %%i in (%%a) do (
if exist %%i echo %%i>nul
if exist %%i (attrib -h -r -s %%i)
(DEL /F /Q %%i)
)
)
for /r %SYSTEMROOT%\system32 %%i in (XP-*.EXE,winvcreg.exe,og.dll,ul.dll,og.EDT,21c0.EDT,21c0.inf,69fe.inf,com.run,dp1.fne,eAPI.fne,internet.fne,krnln.fnr,RegEx.fnr,shell.fne,spec.fne,msdll.dll) do    (
if exist %%i (attrib -h -r -s %%i) & (DEL /F /Q /A %%i)
)>nul
for /r %temp% %%i in (XP-*.EXE,winvcreg.exe,og.dll,ul.dll,og.EDT,21c0.EDT,21c0.inf,69fe.inf,com.run,dp1.fne,eAPI.fne,internet.fne,krnln.fnr,RegEx.fnr,shell.fne,spec.fne,msdll.dll) do    (
if exist %%i (attrib -h -r -s %%i) & (DEL /F /Q /A %%i)
)>nul
attrib -h -r -s %TEMP%\E_4
rd %TEMP%\E_4\
::忘记以下三项内容是否病毒了
attrib -r -h -s -a "C:\RECYCLER\S-1-5-21-796845957-1482476501-682003330-500\Dc9.exe"
attrib -r -h -s -a "C:\RECYCLER\S-1-5-21-796845957-1482476501-682003330-500\Dc10.exe"
attrib -r -h -s -a "C:\RECYCLER\S-1-5-21-796845957-1482476501-682003330-500\Dc11.exe"
DEL /F /Q /A   "C:\RECYCLER\S-1-5-21-796845957-1482476501-682003330-500\Dc9.exe"
DEL /F /Q /A   "C:\RECYCLER\S-1-5-21-796845957-1482476501-682003330-500\Dc10.exe"
DEL /F /Q /A   "C:\RECYCLER\S-1-5-21-796845957-1482476501-682003330-500\Dc11.exe"
echo   清除病毒自启动……
::是否需要修改RUN中一个无名文件夹的二进制数值?
attrib -r -h -s -a "%USERPROFILE%\「开始」菜单\程序\启动\   .lnk"
del "%USERPROFILE%\「开始」菜单\程序\启动\   .lnk" /q /f
for /f "delims=." %%a in (psyf.txt) do (reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v %%a /f)
Del "%ALLUSERSPROFILE%\「开始」菜单\程序\启动\*.*" /q /f
Del "%USERPROFILE%\「开始」菜单\程序\启动\*.*" /q /f
Del "C:\Docume~1\Default User\「开始」菜单\程序\启动\*.*" /q /f
del psyf.txt,fpath.txt
start %SYSTEMROOT%\explorer.exe
cls&echo.
echo   ★ 以下清理移动盘中的EXE病毒,请插入移动盘继续!
echo.
echo      ◇ 移动盘中与文件夹名字相同的EXE程序将被清理。
echo      ◇ 移动盘中的EXE程序大小小于2M的将被清理。
echo      ◇ 请做好备份后继续。
echo.
echo.&pause
cls&echo.
rem 显示移动盘里的所有文件
for /f "skip=1 " %%a in ('wmic logicaldisk where "drivetype='2'" get deviceid') do (
setlocal EnableDelayedexpansion
dir %%a>nul &&IF ERRORLEVEL 0 set tvd=%%a
)>nul
echo.
echo   当前移动盘是:!tvd!
echo.
echo   ★ 正在恢复显示移动盘中的文件,请稍候……(移动盘文件过多可能会影响速度。)
echo.
for /f %%i in ("!tvd!") do attrib %%~di\*.* -s -r -h -a /d /s
rem 删除移动盘中的同名文件夹病毒
setlocal EnableDelayedexpansion
for /r %tvd% %%e in (.) do (
set w2=%%~fe
for /r %tvd% %%i in (*.exe) do (
set w1=%%~dpni
if !w1! == !w2! del /f/a/q %%i
)
)
rem 删除移动盘中特定的EXE程序
for /r %tvd% %%i in (*.exe) do (
if %%~zi lss 2000000 (if exist %%i del /f/q/a %%i)
)
del /a/f/q %tvd%\Autorun.inf
del /a/f/q %tvd%\Autorun.inf.exe
del /a/f/q %tvd%\Autorun.exe
del /a/f/q %tvd%\RECYCLER.exe
del /a/f/q %tvd%\Recycled.exe
del /a/f/q %tvd%\Notepad.exe
del /a/f/q %tvd%\.vbs
echo 甲兵时代移动盘同名文件夹病毒专杀工具>%tvd%\autorun.inf
attrib +a +h +r +s %tvd%\autorun.inf
copy %0 %tvd%>nul
cls&echo.
echo   杀毒完毕!
echo.
goto start
:clean
cls
echo   ★清理系统垃圾★
del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.log
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\*.*
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\*.log
del /f /s /q %windir%\*.tmp
del /f /s /q %windir%\prefetch\*.*
rd /s /q %windir%\temp & md %windir%\temp
rd /s /q %temp% & md %temp%
del /f /q %userprofile%\recent\*.*
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q "%userprofile%\recent\*.*"
cls&echo.
echo   操作完毕!
echo.
goto start
:exit
exit
:auto
Rem 杀进程
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
:clearauto
cls
Echo.
Echo     Autorun 病毒清除与免疫工具rem By Phexon。本文做了部分的修改,敬请原谅。
Echo.
Echo       [1] 一键免疫(推荐!)
Echo       [2] 禁用系统的 Autorun 机制以避免 Autorun 病毒的再次感染
Echo       [3] 仅仅删除所有盘符下的 Autorun 病毒
Echo       [4] 删除并免疫指定盘符的 Autorun 病毒
Echo       [5] 取消免疫指定盘符
Echo       [6] 取消所有盘符的 Autorun 病毒免疫
Echo       [7] 恢复相关注册表项默认值
Echo       [8] 显示被隐藏的文件
Echo       [9] 不显示被隐藏的文件
Echo       [10] 恢复文件的显示隐藏设置功能
Echo       [0] 返回
Echo.
Set /p clearslt= 请输入您的选择(1/2/3/4/5/6/7/8/9/10/0):
If "%clearslt%"=="" Goto clearauto
If "%clearslt%"=="1" Goto clearauto1
If "%clearslt%"=="2" Goto clearauto2
If "%clearslt%"=="3" Goto clearauto3
If "%clearslt%"=="6" Goto clearauto4
If "%clearslt%"=="4" Goto clearauto5
If "%clearslt%"=="5" Goto clearauto6
If "%clearslt%"=="7" Goto clearauto7
if "%clearslt%"=="8" goto xians
if "%clearslt%"=="9" goto yinc
if "%clearslt%"=="10" goto hhsz
If "%clearslt%"=="0" cls&goto start

:clearauto1
cls
echo.
echo.
echo        ★一键免疫,预防病毒自动传播。
echo.
echo        ★清除Autorun.inf和_desktop.ini病毒并免疫,禁用自动播放。
echo.
echo        ★假如弹出对话框提示“WINDOWS-没有软盘”,请点取消即可。
echo.
echo.
pause
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
   For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目录不要删除!...\" & attrib +s +h +r "%%a:\%%b" & Echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
   Del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %%a:\autorun.inf & Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
   ) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
   For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" & md "%%a:\%%b\免疫目录不要删除!...\" & attrib +s +h +r "%%a:\%%b" & Echo Y|cacls "%%a:\%%b" /T /C /P everyone:N >nul 2>nul
   Del /a /f /q %%a:\autorun.inf & md "%%a:\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %%a:\autorun.inf & Echo Y|cacls "%%a:\autorun.inf" /T /C /P everyone:N >nul 2>nul
   ) >nul 2>nul
)
:desk
echo        ★全盘删除所有文件夹下的_desktop.ini
echo        ★假如弹出对话框提示“WINDOWS-没有软盘”,请点取消即可
@echo off
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
    set var=%%i
    set drive=!var:~-2!
    fsutil fsinfo drivetype !drive!|find "固定">nul && del /a /f /s !drive!\_desktop.ini
)
echo.
:clearauto2
cls
echo.
Echo.
Echo        ★禁用自动播放,正在停止相关服务……
echo        ★假如弹出对话框提示“WINDOWS-没有软盘”,请点取消即可
echo.
echo.
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer" /v NoDriveTypeAutoRun /t REG_DWORD /d 0x000000ff /f >nul 2>nul
net stop ShellHWDetection >nul 2>nul
sc config ShellHWDetection start= disabled >nul 2>nul
Rem 添加防止从回收站或仿回收站的目录中直接运行可执行文件的策略
Set REGPATH=HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths
Set SFLAG=/v SaferFlags /t REG_DWORD /d 0x00000000 /f
Set IDATA=/f /v ItemData /d "?:\Recyc?
reg add %REGPATH%\{00ffa5bf-abe7-4901-aacf-4f58aa31217a} %SFLAG%>nul
reg add %REGPATH%\{00ffa5bf-abe7-4901-aacf-4f58aa31217a} %IDATA%\*\*\*\*.*">nul
reg add %REGPATH%\{41fe7eed-c47a-46f6-840a-240796fd03cf} %SFLAG%>nul
reg add %REGPATH%\{41fe7eed-c47a-46f6-840a-240796fd03cf} %IDATA%\*\*\*.*">nul
reg add %REGPATH%\{4e93c91c-a40e-462e-9b89-3b0832d222d9} %SFLAG%>nul
reg add %REGPATH%\{4e93c91c-a40e-462e-9b89-3b0832d222d9} %IDATA%\*.*">nul
reg add %REGPATH%\{5bfc100b-d3fb-450e-88ec-6819ab56a9ff} %SFLAG%>nul
reg add %REGPATH%\{5bfc100b-d3fb-450e-88ec-6819ab56a9ff} %IDATA%\*\*\*\*.*">nul
reg add %REGPATH%\{5c5e2bcd-7057-43f4-830c-e4361d2afadd} %SFLAG%>nul
reg add %REGPATH%\{5c5e2bcd-7057-43f4-830c-e4361d2afadd} %IDATA%\*.*">nul
reg add %REGPATH%\{5f8ff865-0638-4c6e-98de-923e7bc6b330} %SFLAG%>nul
reg add %REGPATH%\{5f8ff865-0638-4c6e-98de-923e7bc6b330} %IDATA%\*\*\*.*">nul
reg add %REGPATH%\{649c1429-0e79-453c-abe9-b5682e035ae7} %SFLAG%>nul
reg add %REGPATH%\{649c1429-0e79-453c-abe9-b5682e035ae7} %IDATA%\*\*.*">nul
reg add %REGPATH%\{718f54b2-c669-4d7b-aeff-18d69f100034} %SFLAG%>nul
reg add %REGPATH%\{718f54b2-c669-4d7b-aeff-18d69f100034} %IDATA%\*\*.*">nul
reg add %REGPATH%\{8385d9d2-80c9-4ac1-a100-ed3e62863d97} %SFLAG%>nul
reg add %REGPATH%\{8385d9d2-80c9-4ac1-a100-ed3e62863d97} %IDATA%\*.*">nul
reg add %REGPATH%\{af2a4fcf-441c-421e-9663-52cd3502cfd7} %SFLAG%>nul
reg add %REGPATH%\{af2a4fcf-441c-421e-9663-52cd3502cfd7} %IDATA%\*\*\*.*">nul
reg add %REGPATH%\{b997f4b2-c037-4e97-b051-31f5d86df802} %SFLAG%>nul
reg add %REGPATH%\{b997f4b2-c037-4e97-b051-31f5d86df802} %IDATA%\*\*.*">nul
reg add %REGPATH%\{d4e7b6ff-d76f-407f-b8bb-ea0835f5babc} %SFLAG%>nul
reg add %REGPATH%\{d4e7b6ff-d76f-407f-b8bb-ea0835f5babc} /f /v ItemData /d "RECYC*.*">nul
Rem 清除喜欢利用回收站的移动磁盘自动运行病毒
For %%a In (c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z) Do (
For %%b In (exe pif com) Do (
   Echo Y|cacls "%%a:\Recycler\*.%%b" /C /T /P everyone:F>nul 2>nul&Echo Y|cacls "%%a:\Recycled\*.%%b" /C /T /P everyone:F>nul 2>nul&Echo Y|cacls "%%a:\Recycled\Recycled\*.%%b" /C /T /P everyone:F>nul 2>nul
   Del /A /F /S /Q "%%a:\Recycler\*.%%b">nul 2>nul&Del /A /F /S /Q "%%a:\Recycled\*.%%b">nul 2>nul&Del /A /F /S /Q "%%a:\Recycled\Recycled\*.%%b">nul 2>nul
   )
)>nul 2>nul
cls
Echo.
echo.
Echo   ★相关服务已停止并禁用,任意键返回……
echo.
echo.
pause >nul
Goto clearauto
:clearauto3
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
   For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" >nul 2>nul
   Del /a /f /q %%a:\autorun.inf >nul 2>nul
   ) >nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
   For /f "tokens=2 delims==" %%b In (%%a:\autorun.inf) Do Del /a /f /q "%%a:\%%b" >nul 2>nul
   Del /a /f /q %%a:\autorun.inf >nul 2>nul
   ) >nul 2>nul
)
cls
Echo   Autorun 病毒清除完毕,任意键返回……
pause>nul
Goto clearauto
:clearauto4
For %%a In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
fsutil fsinfo drivetype %%a: |find /i "固定驱动器" && (
   cacls "%%a:\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%%a:\autorun.inf" & rd /s /q "%%a:\autorun.inf">nul 2>nul
   )>nul 2>nul
fsutil fsinfo drivetype %%a: |find /i "可移动驱动器" && (
   cacls "%%a:\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%%a:\autorun.inf" & rd /s /q "%%a:\autorun.inf">nul 2>nul
   )>nul 2>nul
)
cls
Echo.
Echo   已经解除全部盘符的免疫,任意键返回……
pause>nul
Goto clearauto
:clearauto5
cls
Echo.
Set /p pf=   请输入盘符,如"F:"(不包括引号)
Echo    即将免疫%pf%盘……|find /i ":"||Set pf=%pf%:&&Echo    即将免疫%pf%盘……
taskkill /F /IM SocksA.exe /IM SVOHOST.exe /IM AdobeR.exe /IM ravmone.exe /IM wincfgs.exe /IM doc.exe /IM rose.exe /IM sxs.exe /IM autorun.exe /IM KB20060111.exe /IM tel.xls.exe>nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "固定驱动器" && (
For /f "tokens=2 delims==" %%a In (%pf%\autorun.inf) Do Del /a /f /q "%pf%\%%a" & md "%pf%\%%a\免疫目录不要删除!...\" & attrib +s +h +r "%pf%\%%a" & Echo Y|cacls "%pf%\%%a" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %pf%\autorun.inf & md "%pf%\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %pf%\autorun.inf & Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:N >nul 2>nul
Goto DoneclearAuto
) >nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "可移动驱动器" && (
For /f "tokens=2 delims==" %%a In (%pf%\autorun.inf) Do Del /a /f /q "%pf%\%%a" & md "%pf%\%%a\免疫目录不要删除!...\" & attrib +s +h +r "%pf%\%%a" & Echo Y|cacls "%pf%\%%a" /T /C /P everyone:N >nul 2>nul
Del /a /f /q %pf%\autorun.inf & md "%pf%\autorun.inf\免疫目录不要删除!...\" & attrib +s +h +r %pf%\autorun.inf & Echo Y|cacls "%pf%\autorun.inf" /T /C /P everyone:N >nul 2>nul
Goto DoneclearAuto
) >nul 2>nul
Echo.
Echo   您所输入的盘符不存在或者是只读设备,
Echo   请重新输入
Goto clearauto5
:DoneclearAuto
cls
Echo.
Echo   指定的磁盘 %pf% 已经成功进行了 Autorun 病毒的清除及免疫
Echo.
Echo   [1] 继续免疫其他磁盘
Echo   [0] 返回主菜单
Set /p choice=   请输入您的选择(1/0):
If %choice%="" Goto DoneclearAuto
If %choice%="1" Goto clearauto5
If %choice%="0" Goto clearauto
:clearauto6
cls
Echo.
Set /p pf=   请输入盘符,如"F:"(不包括引号)
Echo    即将取消免疫%pf%盘……|find /i ":"||Set pf=%pf%:&&Echo    即将取消免疫%pf%盘……
fsutil fsinfo drivetype %pf% |find /i "固定驱动器" && (
cacls "%pf%\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%pf%\autorun.inf" & rd /s /q "%pf%\autorun.inf">nul 2>nul
Goto DoneUnauto
)>nul 2>nul
fsutil fsinfo drivetype %pf% |find /i "可移动驱动器" && (
cacls "%pf%\autorun.inf" /T /C /P everyone:F&Del /a /f /q "%pf%\autorun.inf" & rd /s /q "%pf%\autorun.inf">nul 2>nul
Goto DoneUnauto
)>nul 2>nul
Echo.
Echo   您所输入的盘符不存在或者是只读设备,
Echo   请重新输入
Goto clearauto6
:DoneUnauto
cls
Echo.
Echo   指定的磁盘 %pf% 已经成功解除了 Autorun 病毒免疫
Echo.
Echo   [1] 继续解除免疫其他磁盘
Echo   [0] 返回主菜单
Set choice=
Set /p choice=   请输入您的选择(1/0):
If %choice%="" Goto DoneUnauto
If %choice%="1" Goto clearauto6
If %choice%="0" Goto clearauto
:clearauto7
cls
Rem 防止在资源管理器中彻底隐藏文件、禁止文件等
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /v CheckedValue /t REG_DWORD /d 0x00000001 /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\DisallowRun" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v DisallowRun /f>nul 2>nul
Rem 防止转移启动组位置
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Startup /d "%USERPROFILE%\「开始」菜单\程序\启动" /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Startup" /d "%ALLUSERSPROFILE%\「开始」菜单\程序\启动" /f>nul 2>nul
Echo.
Echo   相关注册表恢复完毕,任意键返回……
pause>nul
Goto clearauto
:xians
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t reg_dword /d 1 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 0 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t reg_dword /d 1 /f
cls&echo.
Echo   操作完毕,任意键返回……
pause>nul
Goto clearauto
:yinc
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t reg_dword /d 00000000 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 00000001 /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t reg_dword /d 00000000 /f
cls&echo.
Echo   操作完毕,任意键返回……
pause>nul
Goto clearauto
:hhsz
echo.
echo        恢复注册表中不给设置显示隐藏文件的项目,请稍侯......
echo.
echo.
ECHO Windows Registry Editor Version 5.00>SHOWALL.reg
ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL]>>SHOWALL.reg
ECHO "CheckedValue"=->>SHOWALL.reg
ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL]>>SHOWALL.reg
ECHO "CheckedValue"=dword:00000001>>SHOWALL.reg
cls&echo.
Echo   操作完毕,任意键返回……
pause>nul
Goto clearauto

cyjian
Spammer
Spammer

Posts : 211
Points : 25615
Reputation : 0
Join date : 2014-06-18

View user profile

Back to top Go down

View previous topic View next topic Back to top


 
Permissions in this forum:
You cannot reply to topics in this forum